system/services/nginx/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70

{lib, ...}: let
  domains = import ./hosts.nix {};
  importedRedirects = import ./redirects.nix {};
  mkRedirect = {
    key,
    value,
  }: {
    name = key;
    value = {
      forceSSL = true;
      enableACME = true;
      locations."/".return = "301 ${value}";
    };
  };
  mkVirtHost = {
    domain,
    root,
    url,
    extraSettings ? {},
  }: {
    name = "${domain}";
    value =
      lib.recursiveUpdate {
        forceSSL = true;
        enableACME = true;
        root = "${root}";
      }
      extraSettings;
  };

  mkNixSyncRepository = {
    domain,
    root,
    url,
    extraSettings ? {},
  }: {
    name = "${domain}";
    value = {
      path = "${root}";
      uri = "${url}";
      inherit extraSettings;
    };
  };

  virtHosts = builtins.listToAttrs (builtins.map mkVirtHost domains);
  nixSyncRepositories = builtins.listToAttrs (builtins.map mkNixSyncRepository domains);
  redirects = builtins.listToAttrs (builtins.map mkRedirect importedRedirects);
in {
  security.acme = {
    acceptTerms = true;
    defaults = {
      email = "admin@vhack.eu";
      webroot = "/var/lib/acme/acme-challenge";
    };
  };

  networking.firewall = {
    allowedTCPPorts = [80 443];
  };
  services.nginx = {
    enable = true;
    # The merge here is fine, as no domain should be specified twice
    virtualHosts = virtHosts // redirects;
  };

  services.nix-sync = {
    enable = true;
    repositories = nixSyncRepositories;
  };
}