system/impermanence/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

{
  config,
  lib,
  ...
}: let
  cfg = config.soispha.impermanence;
  networkmanager =
    if config.networking.networkmanager.enable
    then [
      "/etc/NetworkManager" # store the networkmanager configs
    ]
    else [];
  secureboot =
    if config.boot.lanzaboote.enable
    then [
      "/etc/secureboot"
    ]
    else [];
  directories =
    [
      "/etc/nixos"
      "/var/log"
      # TODO: the following entries need to be checked
      #"/var/lib/bluetooth"
      #"/var/lib/nixos"
      #"/var/lib/systemd/coredump"
    ]
    ++ networkmanager
    ++ secureboot;
in {
  options.soispha.impermanence = {
    enable = lib.mkOption {
      type = lib.types.bool;
      default = true;
      description = lib.mdDoc "Disk setup with disko";
    };
  };
  config = lib.mkIf cfg.enable {
    # needed for the hm impermanence config
    programs.fuse.userAllowOther = true;

    environment.persistence = {
      "/srv" = {
        hideMounts = true;
        inherit directories;
        files = [
          "/etc/machine-id"
        ];
      };
    };
  };
}