From d9ab6c7ea59d29af3ae8c29c7367fe0e8808f5db Mon Sep 17 00:00:00 2001
From: Benedikt Peetz <benedikt.peetz@b-peetz.de>
Date: Wed, 25 Dec 2024 18:25:51 +0100
Subject: refactor(hosts): Use a `by-name` structure and construct all host
 depended values

This allows us to outsource the host-handling from the `flake.nix` file.
---
 hosts/default.nix | 41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 hosts/default.nix

(limited to 'hosts/default.nix')

diff --git a/hosts/default.nix b/hosts/default.nix
new file mode 100644
index 0000000..f53ee35
--- /dev/null
+++ b/hosts/default.nix
@@ -0,0 +1,41 @@
+{
+  pkgs,
+  nixLib,
+  nixpkgs,
+  specialArgs,
+  extraModules,
+  deployPackage,
+}: let
+  hostnames = builtins.fromTOML (builtins.readFile ./host-names.toml);
+
+  hosts = nixLib.mkByName {
+    useShards = false;
+    baseDirectory = ./by-name;
+    fileName = "configuration.nix";
+    finalizeFunction = name: value: value;
+  };
+
+  mkNixosConfiguration = _: value:
+    nixpkgs.lib.nixosSystem {
+      system = "x86_64-linux";
+      inherit specialArgs;
+      modules =
+        extraModules
+        ++ [
+          ../modules
+          value
+        ];
+    };
+  nixosConfigurations = builtins.mapAttrs mkNixosConfiguration hosts;
+
+  mkDeploy = name: _: {
+    hostname = hostnames."${name}";
+    profiles.system = {
+      user = "root";
+      path = deployPackage.lib.activate.nixos nixosConfigurations."${name}";
+    };
+  };
+  deploy = {nodes = builtins.mapAttrs mkDeploy hosts;};
+in {
+  inherit nixosConfigurations deploy;
+}
-- 
cgit 1.4.1