modules/system/impermanence/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

{
  config,
  lib,
  ...
}: let
  cfg = config.soispha.impermanence;
in {
  options.soispha.impermanence = {
    enable = lib.mkEnableOption "persisting directories and files with impermanence";

    directories = lib.mkOption {
      type = lib.types.listOf lib.types.str;
      default =
        [
          "/etc/nixos"
          "/var/log"
          "/var/lib/systemd"
          "/var/lib/nixos"
        ]
        ++ lib.optional config.networking.networkmanager.enable "/etc/NetworkManager"
        ++ lib.optional config.boot.lanzaboote.enable "/etc/secureboot"
        ++ lib.optional config.hardware.bluetooth.enable "/var/lib/bluetooth"
        ++ lib.optional config.virtualisation.waydroid.enable "/var/lib/waydroid"
        ++ lib.optional config.services.postgresql.enable "/var/lib/postgresql";

      defaultText = lib.literalExpression ''
        [
          "/etc/nixos"
          "/var/log"
          "/var/lib/systemd"
          "/var/lib/nixos"
        ]
        ++ lib.optional config.networking.networkmanager.enable "/etc/NetworkManager"
        ++ lib.optional config.boot.lanzaboote.enable "/etc/secureboot"
        ++ lib.optional config.hardware.bluetooth.enable "/var/lib/bluetooth"
        ++ lib.optional config.virtualisation.waydroid.enable "/var/lib/waydroid"
        ++ lib.optional config.services.postgresql.enable "/var/lib/postgresql"
      '';
      description = "The directories to persist";
    };
  };

  config = lib.mkIf cfg.enable {
    # needed for the hm impermanence config
    programs.fuse.userAllowOther = true;

    environment.persistence = {
      "/srv" = {
        hideMounts = true;
        inherit (cfg) directories;
        files = [
          "/etc/machine-id"
        ];
      };
    };
  };
}