{
  lib,
  pkgs,
  config,
  ...
}: let
  backup-script = pkgs.writeShellScriptBin "backsnap" ''
    ${pkgs.util-linux}/bin/mount --mkdir "/dev/disk/by-uuid/${cfg.backupDiskUuid}" "/run/media/${cfg.backupDiskUuid}";
    ${pkgs.snap-sync-forked}/bin/snap-sync-forked --UUID "${cfg.backupDiskUuid}" --noconfirm;
    ${pkgs.util-linux}/bin/umount "/run/media/${cfg.backupDiskUuid}";
  '';

  cfg = config.soispha.services.backup;
in {
  options.soispha.services.backup = {
    enable = lib.mkEnableOption "backups with my forked snap-sync";
    backupDiskUuid = lib.mkOption {
      type = lib.types.str;
      example = lib.literalExpression "d1d20ae7-3d8a-44da-86da-677dbbb10c89";
      description = "The UUID of the backup disk";
    };
  };

  config = lib.mkIf cfg.enable {
    systemd = {
      services.backup = {
        wantedBy = lib.mkForce [];
        unitConfig = {
          Description = "Backup the last snapshots of the persitent-storage subvolume.";
        };
        serviceConfig = {
          Type = "oneshot";
          ExecStart = "${backup-script}/bin/backsnap";
        };
      };

      timers.backup = {
        wantedBy = ["timers.target"];
        unitConfig = {
          Description = "Backup 15min after boot and every 8 hours";
        };
        timerConfig = {
          OnBootSec = "15min";
          OnUnitActiveSec = "8h";
        };
      };
    };
  };
}