{
  nixosConfig,
  sysLib,
  system,
  pkgs,
  ...
}: let
  makeScript = {
    name,
    dependencies,
    ...
  }:
    sysLib.writeShellScript {
      inherit name;
      src = ./scripts/${name}.sh;
      dependencies = dependencies ++ (builtins.attrValues {inherit (pkgs) dash;});
    }
    + "/bin/${name}";
in {
  xdg.configFile."yambar/config.yml".source = pkgs.substituteAll {
    src =
      if nixosConfig.soispha.laptop.enable
      then ./config/laptop.yml
      else ./config/config.yml;

    backlight =
      if nixosConfig.soispha.laptop.enable
      then nixosConfig.soispha.laptop.backlight
      else "";

    mpd_song_name_script = makeScript {
      dependencies = builtins.attrValues {inherit (pkgs) mpc-cli;};
      name = "mpd_song_name";
    };

    volume_script = makeScript {
      dependencies = builtins.attrValues {inherit (pkgs) pulseaudio gawk coreutils;};
      name = "sound-volume";
    };

    cpu_script = pkgs.yambar-cpu;

    memory_script = pkgs.yambar-memory;

    disk_script = makeScript {
      dependencies = builtins.attrValues {inherit (pkgs) gawk btrfs-progs coreutils;};
      name = "disk";
    };
  };
}