From 3f600ab07dbad3b6dd7655587ddea158b19aea71 Mon Sep 17 00:00:00 2001
From: Soispha <soispha@vhack.eu>
Date: Sat, 26 Aug 2023 23:42:21 +0200
Subject: Refactor(treewide): Abbreviate path names

---
 sys/svcs/backup/default.nix | 67 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 sys/svcs/backup/default.nix

(limited to 'sys/svcs/backup/default.nix')

diff --git a/sys/svcs/backup/default.nix b/sys/svcs/backup/default.nix
new file mode 100644
index 00000000..171f1043
--- /dev/null
+++ b/sys/svcs/backup/default.nix
@@ -0,0 +1,67 @@
+{
+  lib,
+  sysLib,
+  pkgs,
+  config,
+  ...
+}: let
+  snap-sync-forked = sysLib.writeShellScriptWithLibrary {
+    name = "snap-sync-forked";
+    src = ./snap-sync-forked;
+    dependencies = with pkgs; [
+      bash
+      btrfs-progs
+      coreutils
+      gawk
+      gnugrep
+      snapper
+      util-linux
+
+      # optional:
+      libnotify
+      openssh
+      pv
+      rsync
+      sudo
+    ];
+  };
+  backup-script = pkgs.writeShellScriptBin "backsnap" ''
+    ${pkgs.util-linux}/bin/mount --mkdir "/dev/disk/by-uuid/${cfg.backupDiskUuid}" "/run/media/${cfg.backupDiskUuid}";
+    ${snap-sync-forked}/bin/snap-sync-forked --UUID "${cfg.backupDiskUuid}" --noconfirm;
+    ${pkgs.util-linux}/bin/umount "/run/media/${cfg.backupDiskUuid}";
+  '';
+  cfg = config.soispha.fs.backup;
+in {
+  options.soispha.fs.backup = {
+    enable = lib.mkEnableOption (lib.mdDoc "backups with snap-sync");
+    backupDiskUuid = lib.mkOption {
+      type = lib.types.str;
+      example = lib.literalExpression "d1d20ae7-3d8a-44da-86da-677dbbb10c89";
+      description = lib.mdDoc "The UUID of the backup disk";
+    };
+  };
+  config = lib.mkIf cfg.enable {
+    systemd = {
+      services.backup = {
+        wantedBy = lib.mkForce [];
+        unitConfig = {
+          Description = "Backup the last snapshots of the persitent-storage subvolume.";
+        };
+        serviceConfig = {
+          Type = "oneshot";
+          ExecStart = "${backup-script}/bin/backsnap";
+        };
+      };
+      timers.backup = {
+        wantedBy = ["timers.target"];
+        unitConfig = {
+          Description = "Backup 15min after boot and every 8 hours";
+        };
+        timerConfig = {
+          OnBootSec = "15min";
+          OnUnitActiveSec = "8h";
+        };
+      };
+    };
+  };
+}
-- 
cgit 1.4.1