From 368cb6b0d25db2ae23be42ad51584de059997e51 Mon Sep 17 00:00:00 2001
From: Benedikt Peetz <benedikt.peetz@b-peetz.de>
Date: Mon, 20 May 2024 16:10:21 +0200
Subject: refactor(sys): Modularize and move to `modules/system` or `pkgs`

---
 modules/system/services/backup/default.nix | 49 ++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 modules/system/services/backup/default.nix

(limited to 'modules/system/services/backup/default.nix')

diff --git a/modules/system/services/backup/default.nix b/modules/system/services/backup/default.nix
new file mode 100644
index 00000000..705dcf23
--- /dev/null
+++ b/modules/system/services/backup/default.nix
@@ -0,0 +1,49 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}: let
+  backup-script = pkgs.writeShellScriptBin "backsnap" ''
+    ${pkgs.util-linux}/bin/mount --mkdir "/dev/disk/by-uuid/${cfg.backupDiskUuid}" "/run/media/${cfg.backupDiskUuid}";
+    ${pkgs.snap-sync-forked}/bin/snap-sync-forked --UUID "${cfg.backupDiskUuid}" --noconfirm;
+    ${pkgs.util-linux}/bin/umount "/run/media/${cfg.backupDiskUuid}";
+  '';
+
+  cfg = config.soispha.backup;
+in {
+  options.soispha.backup = {
+    enable = lib.mkEnableOption "backups with my forked snap-sync";
+    backupDiskUuid = lib.mkOption {
+      type = lib.types.str;
+      example = lib.literalExpression "d1d20ae7-3d8a-44da-86da-677dbbb10c89";
+      description = "The UUID of the backup disk";
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    systemd = {
+      services.backup = {
+        wantedBy = lib.mkForce [];
+        unitConfig = {
+          Description = "Backup the last snapshots of the persitent-storage subvolume.";
+        };
+        serviceConfig = {
+          Type = "oneshot";
+          ExecStart = "${backup-script}/bin/backsnap";
+        };
+      };
+
+      timers.backup = {
+        wantedBy = ["timers.target"];
+        unitConfig = {
+          Description = "Backup 15min after boot and every 8 hours";
+        };
+        timerConfig = {
+          OnBootSec = "15min";
+          OnUnitActiveSec = "8h";
+        };
+      };
+    };
+  };
+}
-- 
cgit 1.4.1