{
  description = "TODO";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };

    flake_version_update = {
      url = "git+https://codeberg.org/soispha/flake_version_update.git";
      inputs = {
        systems.follows = "systems";
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
      };
    };
    shell_library = {
      url = "git+https://codeberg.org/soispha/shell_library.git";
      inputs = {
        flake-utils.follows = "flake-utils";
        nixpkgs.follows = "nixpkgs";
        systems.follows = "systems";
        flake_version_update.follows = "flake_version_update";
      };
    };

    # inputs for following
    systems = {
      url = "github:nix-systems/x86_64-linux"; # only evaluate for this system
    };
    flake-compat = {
      url = "github:edolstra/flake-compat";
      flake = false;
    };
    flake-utils = {
      url = "github:numtide/flake-utils";
      inputs = {
        systems.follows = "systems";
      };
    };
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
    treefmt-nix,
    flake_version_update,
    shell_library,
    ...
  }:
    flake-utils.lib.eachDefaultSystem (system: let
      pkgs = nixpkgs.legacyPackages."${system}";

      treefmtEval = import ./treefmt.nix {inherit treefmt-nix pkgs;};

      # This version is set automatically on `cog bump --auto`;
      version = "v0.1.0"; # GUIDING VERSION STRING
      pname = "TODO";

      build = shell_library.lib.${system}.writeShellScript {
        inherit version;
        name = pname;

        src = ./src/main.sh;
        dependencies = with pkgs; [dash];

        replacementStrings = null;
        generateCompletions = false;
        keepPath = false;
        wrap = true;
      };

      manual = pkgs.stdenv.mkDerivation {
        name = "${pname}-manual";
        inherit version;

        src = ./docs;
        nativeBuildInputs = with pkgs; [pandoc];

        buildPhase = ''
          mkdir --parents $out/docs;

          pandoc "./${pname}.1.md" -s -t man > $out/docs/${pname}.1
        '';

        installPhase = ''
          install -D $out/docs/${pname}.1  $out/share/man/man1/${pname};
        '';
      };
    in {
      packages.default = pkgs.symlinkJoin {
        name = pname;

        paths = [manual build];
      };

      checks = {
        inherit build;
        formatting = treefmtEval.config.build.check self;
      };
      formatter = treefmtEval.config.build.wrapper;

      devShells.default = pkgs.mkShell {
        packages = with pkgs; [
          cocogitto
          flake_version_update.packages."${system}".default

          licensure
        ];
      };
    });
}