From 4f2b735472eb921b5edd91c502e0a47d5e4d0cd2 Mon Sep 17 00:00:00 2001
From: Benedikt Peetz <benedikt.peetz@b-peetz.de>
Date: Tue, 11 Jun 2024 09:48:15 +0200
Subject: chore(build): Update

---
 build/awk/flake.nix | 104 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 104 insertions(+)
 create mode 100644 build/awk/flake.nix

(limited to 'build/awk/flake.nix')

diff --git a/build/awk/flake.nix b/build/awk/flake.nix
new file mode 100644
index 0000000..4f61840
--- /dev/null
+++ b/build/awk/flake.nix
@@ -0,0 +1,104 @@
+{
+  description = "%INIT_DESCRIPTION";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+
+    treefmt-nix = {
+      url = "github:numtide/treefmt-nix";
+      inputs = {
+        nixpkgs.follows = "nixpkgs";
+      };
+    };
+
+    flake_version_update = {
+      url = "git+https://codeberg.org/soispha/flake_version_update.git";
+      inputs = {
+        systems.follows = "systems";
+        nixpkgs.follows = "nixpkgs";
+        flake-utils.follows = "flake-utils";
+      };
+    };
+
+    # inputs for following
+    systems = {
+      url = "github:nix-systems/x86_64-linux"; # only evaluate for this system
+    };
+    flake-compat = {
+      url = "github:edolstra/flake-compat";
+      flake = false;
+    };
+    flake-utils = {
+      url = "github:numtide/flake-utils";
+      inputs = {
+        systems.follows = "systems";
+      };
+    };
+  };
+
+  outputs = {
+    self,
+    nixpkgs,
+    flake-utils,
+    treefmt-nix,
+    flake_version_update,
+    ...
+  }:
+    flake-utils.lib.eachDefaultSystem (system: let
+      pkgs = nixpkgs.legacyPackages.${system};
+      treefmtEval = import ./treefmt.nix {inherit treefmt-nix pkgs;};
+
+      # This version is set automatically on `cog bump --auto`;
+      version = "v%INIT_APPLICATION_VERSION"; # GUIDING VERSION STRING
+
+      pname = "%INIT_APPLICATION_NAME";
+
+      build = pkgs.stdenv.mkDerivation {
+        inherit version pname;
+        src = ./.;
+
+        nativeBuildInputs = with pkgs; [pandoc fd];
+
+        dependencies = with pkgs; [gawk];
+
+        buildPhase = ''
+          mkdir --parents $out/docs;
+          pandoc ./docs/${pname}.1.md -s -t man  > $out/docs/${pname}.1
+        '';
+
+        installPhase = ''
+          install -D $out/docs/${pname}.1  $out/share/man/man1/${pname};
+
+          install -D ./src/${pname}.awk $out/bin/${pname}.awk;
+
+          # Generate a wrapper script.
+          cat << EOF > $out/bin/${pname}
+          #! /usr/bin/env sh
+          $out/bin/${pname}.awk -- "\$@"
+          EOF
+
+          # Set correct permissions
+          chmod +x $out/bin/${pname}
+        '';
+      };
+    in {
+      packages.default = build;
+      checks = {
+        inherit build;
+        formatting = treefmtEval.config.build.check self;
+      };
+      formatter = treefmtEval.config.build.wrapper;
+
+      devShells.default = pkgs.mkShell {
+        packages = with pkgs; [
+          cocogitto
+          flake_version_update.packages."${system}".default
+
+          gawk
+          licensure
+        ];
+      };
+    });
+}
+# vim: ts=2
+
-- 
cgit 1.4.1