feat(c): Update to be in line with the my SOTA

1 files changed, 73 insertions, 0 deletions

diff --git a/templates/c/flake.nix b/templates/c/flake.nix
new file mode 100644
index 0000000..cd4200c
--- /dev/null
+++ b/templates/c/flake.nix
@@ -0,0 +1,73 @@
+{
+  description = "TODO";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+
+    treefmt-nix = {
+      url = "github:numtide/treefmt-nix";
+      inputs = {
+        nixpkgs.follows = "nixpkgs";
+      };
+    };
+
+    # inputs for following
+    systems = {
+      url = "github:nix-systems/x86_64-linux"; # only evaluate for this system
+    };
+    flake-compat = {
+      url = "github:edolstra/flake-compat";
+      flake = false;
+    };
+    flake-utils = {
+      url = "github:numtide/flake-utils";
+      inputs = {
+        systems.follows = "systems";
+      };
+    };
+  };
+
+  outputs = {
+    self,
+    nixpkgs,
+    flake-utils,
+    treefmt-nix,
+    ...
+  }:
+    flake-utils.lib.eachDefaultSystem (system: let
+      pkgs = nixpkgs.legacyPackages."${system}";
+
+      nativeBuildInputs = with pkgs; [valgrind pandoc];
+      treefmtEval = import ./treefmt.nix {inherit treefmt-nix pkgs;};
+
+      pname = "TODO";
+      version = "0.1";
+
+      build = pkgs.stdenv.mkDerivation {
+        inherit pname version;
+
+        src = ./.;
+        makeFlags = ["PREFIX=${placeholder "out"}"];
+        inherit nativeBuildInputs;
+      };
+    in {
+      packages.default = build;
+      checks = {
+        inherit build;
+        formatting = treefmtEval.config.build.check self;
+      };
+      formatter = treefmtEval.config.build.wrapper;
+
+      devShells.default = pkgs.mkShell {
+        packages = with pkgs; [
+          cocogitto
+        ];
+        inherit nativeBuildInputs;
+        env = {
+          GCC_COLORS = "error=01;31:warning=01;35:note=01;36:caret=01;32:locus=01:quote=01";
+        };
+      };
+    });
+}
+# vim: ts=2
+