{
  description = "My Nixos system configuration";

  inputs = {
    nixpkgs.url = "github:NixOs/nixpkgs/nixos-unstable";
    nixpkgs-stable.url = "github:NixOs/nixpkgs/nixos-23.05";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    impermanence.url = "github:nix-community/impermanence";

    # inputs for following
    agenix = {
      url = "github:ryantm/agenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    ragenix = {
      url = "github:yaxitech/ragenix";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        agenix.follows = "agenix";
        flake-utils.follows = "flake-utils";
        rust-overlay.follows = "rust-overlay";
        crane.follows = "crane";
      };
    };
    nixvim = {
      url = "github:nix-community/nixvim";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
      };
    };
    lanzaboote = {
      url = "github:nix-community/lanzaboote/v0.3.0";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    systems = {
      url = "path:./flake/systems.nix"; #  evaluate for 32 and 64 Bit Linux
      flake = false;
    };
    sops-nix = {
      url = "github:Mic92/sops-nix";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        nixpkgs-stable.follows = "nixpkgs-stable";
      };
    };
    flake-compat = {
      url = "github:edolstra/flake-compat";
      flake = false;
    };
    crane = {
      url = "github:ipetkov/crane";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };
    flake-utils = {
      url = "github:numtide/flake-utils";
      inputs = {
        systems.follows = "systems";
      };
    };
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
      };
    };

    shell_library = {
      url = "git+https://codeberg.org/soispha/shell_library.git";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
        systems.follows = "systems";
      };
    };
    river_init_lesser = {
      url = "git+https://codeberg.org/soispha/river_keymap_init.git";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        crane.follows = "crane";
        flake-utils.follows = "flake-utils";
        rust-overlay.follows = "rust-overlay";
        flake-compat.follows = "flake-compat";
      };
    };
    yambar_cpu = {
      url = "git+https://codeberg.org/soispha/yambar_cpu.git";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        crane.follows = "crane";
        flake-utils.follows = "flake-utils";
      };
    };
    yambar_memory = {
      url = "git+https://codeberg.org/soispha/yambar_memory.git";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
      };
    };
    #grades = {
    #     url = "git+https://codeberg.org/soispha/grades.git";
    #     inputs = {
    #       nixpkgs.follows = "unstable";
    #       crane.follows = "crane";
    #       flake-utils.follows = "flake-utils";
    #       rust-overlay.follows = "rust-overlay";
    #     };
    #   };
    prismlauncher = {
      url = "github:PrismLauncher/PrismLauncher";
    };
    wl-togglescreens = {
      url = "git+https://git.project-insanity.org/onny/wl-togglescreens.git?ref=main";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
  #}}}
  outputs = {
    self,
    nixpkgs,
    home-manager,
    shell_library,
    river_init_lesser,
    yambar_cpu,
    yambar_memory,
    #grades,
    prismlauncher,
    lanzaboote,
    nixvim,
    impermanence,
    wl-togglescreens,
    sops-nix,
    flake-utils,
    agenix,
    ragenix,
    ...
  } @ attrs: let
    utils = flake-utils.lib;
    system = "x86_64-linux";
    pkgs = import nixpkgs {
      inherit system;
      overlays = [nixvim.overlays.default];
    };
    sysLib = shell_library.lib.${system};
    defaultModules = [
      impermanence.nixosModules.impermanence
      lanzaboote.nixosModules.lanzaboote
      home-manager.nixosModules.home-manager
      sops-nix.nixosModules.sops
      agenix.nixosModules.default
      {
        home-manager = {
          useGlobalPkgs = true;
          useUserPackages = true;
          users.sils = import ./users/sils;
          extraSpecialArgs = attrs;
        };
      }
    ];
  in
    {
      nixosConfigurations = {
        thinklappi = nixpkgs.lib.nixosSystem {
          inherit system;
          specialArgs = attrs;
          modules =
            [
              ./hosts/thinklappi
            ]
            ++ defaultModules;
        };
        thinklappi-bootstrap = nixpkgs.lib.nixosSystem {
          inherit system;
          specialArgs = attrs;
          modules = [
            ./hosts/thinklappi-bootstrap
            lanzaboote.nixosModules.lanzaboote
          ];
        };
      };
    }
    // utils.eachDefaultSystem (system: {
      devShells.default = pkgs.mkShell {
        packages = with pkgs; [
          nil
          statix
          alejandra
          sops
          ragenix.packages."${system}".default
        ];
      };

      formatter = pkgs.alejandra;
    });
}