{
  description = "My Nixos system configuration";

  inputs = {
    nixpkgs.url = "github:NixOs/nixpkgs/nixos-unstable";
    nixpkgs-stable.url = "github:NixOs/nixpkgs/nixos-23.05";
    nixpkgs-lib.url = "github:NixOs/nixpkgs/nixos-unstable?dir=lib";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    impermanence.url = "github:nix-community/impermanence";

    nix-darwin = {
      url = "github:lnl7/nix-darwin";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    gitignore = {
      url = "github:hercules-ci/gitignore.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    pre-commit-hooks-nix = {
      url = "github:cachix/pre-commit-hooks.nix";
      inputs = {
        flake-compat.follows = "flake-compat";
        flake-utils.follows = "flake-utils";
        gitignore.follows = "gitignore";
        nixpkgs.follows = "nixpkgs";
        nixpkgs-stable.follows = "nixpkgs-stable";
      };
    };

    # inputs for following
    agenix = {
      url = "github:ryantm/agenix";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        home-manager.follows = "home-manager";
        darwin.follows = "nix-darwin";
      };
    };
    ragenix = {
      url = "github:yaxitech/ragenix";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        agenix.follows = "agenix";
        flake-utils.follows = "flake-utils";
        rust-overlay.follows = "rust-overlay";
        crane.follows = "crane";
      };
    };
    poetry2nix = {
      url = "github:nix-community/poetry2nix";
      inputs = {
        flake-utils.follows = "flake-utils";
        nixpkgs.follows = "nixpkgs";
        nix-github-actions.follows = "nix-github-actions";
        treefmt-nix.follows = "treefmt-nix";
        systems.follows = "systems";
      };
    };
    nix-github-actions = {
      url = "github:nix-community/nix-github-actions";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixvim = {
      url = "github:nix-community/nixvim";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
        pre-commit-hooks.follows = "pre-commit-hooks-nix";
      };
    };
    lanzaboote = {
      url = "github:nix-community/lanzaboote/v0.3.0";
      inputs = {
        crane.follows = "crane";
        nixpkgs.follows = "nixpkgs";
        flake-compat.follows = "flake-compat";
        flake-parts = {
          follows = "flake-parts";
          inputs.nixpkgs-lib.follows = "nixpkgs-lib";
        };
        flake-utils.follows = "flake-utils";
        pre-commit-hooks-nix.follows = "pre-commit-hooks-nix";
        rust-overlay.follows = "rust-overlay";
      };
    };
    systems = {
      url = "git+https://codeberg.org/sils/systems"; #  specify systems to evaluate
    };
    sops-nix = {
      url = "github:Mic92/sops-nix";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        nixpkgs-stable.follows = "nixpkgs-stable";
      };
    };
    flake-compat = {
      url = "github:edolstra/flake-compat";
      flake = false;
    };
    crane = {
      url = "github:ipetkov/crane";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };
    flake-utils = {
      url = "github:numtide/flake-utils";
      inputs = {
        systems.follows = "systems";
      };
    };
    flake-parts = {
      url = "github:hercules-ci/flake-parts";
      inputs.nixpkgs-lib.follows = "nixpkgs-lib";
    };
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
      };
    };
    prismlauncher = {
      url = "github:PrismLauncher/PrismLauncher";
      inputs = {
        flake-compat.follows = "flake-compat";
        flake-parts.follows = "flake-parts";
        libnbtplusplus.follows = "libnbtplusplus";
        nix-filter.follows = "nix-filter";
        nixpkgs.follows = "nixpkgs";
        pre-commit-hooks.follows = "pre-commit-hooks-nix";
      };
    };
    nix-filter = {
      url = "github:numtide/nix-filter";
    };
    libnbtplusplus = {
      url = "github:PrismLauncher/libnbtplusplus";
      flake = false;
    };
    wl-togglescreens = {
      url = "git+https://git.project-insanity.org/onny/wl-togglescreens.git?ref=main";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
  #}}}
  outputs = {
    self,
    nixpkgs,
    home-manager,
    prismlauncher,
    lanzaboote,
    nixvim,
    impermanence,
    wl-togglescreens,
    sops-nix,
    flake-utils,
    agenix,
    ragenix,
    ...
  } @ attrs:
    flake-utils.lib.eachDefaultSystem (system: let
      pkgs = import nixpkgs {
        inherit system;
        overlays = [nixvim.overlays.default];
      };
      nixVimConfig = import ./users/sils/nixvim/config.nix;
      nvim = nixvim.legacyPackages."${system}".makeNixvim nixVimConfig;
    in {
      devShells.default = pkgs.mkShell {
        packages = with pkgs; [
          nil
          statix
          alejandra
          sops
          ragenix.packages."${system}".default
        ];
      };

      formatter = pkgs.alejandra;

      packages = {
        inherit nvim;
        default = nvim;
      };
      checks = {
        nvim = nixvim.lib.${system}.check.mkTestDerivationFromNvim {
          inherit nvim;
          name = "My NixVim Configuration";
        };
      };
    })
    // {
      nixosConfigurations = import ./flake/nixosConfigurations {
        inherit
          self
          nixpkgs
          home-manager
          prismlauncher
          lanzaboote
          nixvim
          impermanence
          wl-togglescreens
          sops-nix
          flake-utils
          agenix
          ragenix
          ;
      };
    };
}