{
  description = "Die Vergütungsordnung";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };
    flake_version_update = {
      url = "git+https://codeberg.org/soispha/flake_version_update.git";
      inputs = {
        systems.follows = "systems";
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
      };
    };
    lpm = {
      url = "git+https://codeberg.org/Soispha/lpm.git";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-compat.follows = "flake-compat";
        flake-utils.follows = "flake-utils";
        rust-overlay.follows = "rust-overlay";
        crane.follows = "crane";
        systems.follows = "systems";
      };
    };

    # inputs for following
    systems = {
      url = "github:nix-systems/x86_64-linux"; # only evaluate for this system
    };
    flake-compat = {
      url = "github:edolstra/flake-compat";
      flake = false;
    };
    flake-utils = {
      url = "github:numtide/flake-utils";
      inputs = {
        systems.follows = "systems";
      };
    };
    crane = {
      url = "github:ipetkov/crane";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
      };
    };
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
    treefmt-nix,
    lpm,
    flake_version_update,
    ...
  }:
    flake-utils.lib.eachDefaultSystem (system: let
      pkgs = nixpkgs.legacyPackages.${system};

      # This version is set automatically on `cog bump --auto`;
      version = "v0.1.0"; # GUIDING VERSION STRING

      # TODO reduce to the needed ones
      texlive = pkgs.texlive.combined.scheme-full;

      treefmtEval = import ./treefmt.nix {inherit treefmt-nix pkgs;};

      build = pkgs.stdenv.mkDerivation {
        pname = "verguetungsordnung";
        inherit version;
        src = ./.;

        buildInputs = [
          texlive
        ];

        # Run local
        preferLocalBuild = true;
        allowSubstitutes = false;

        buildPhase = ''
          # TODO: I have no idea, why calling it with `./build.sh` does not work <2024-03-20>
          bash ./build.sh
        '';

        installPhase = ''
          install -D ./build/main.pdf "$out/verguetungsordnung.pdf";
        '';
      };
    in {
      packages.default = build;

      checks = {
        inherit build;
        formatting = treefmtEval.config.build.check self;
      };

      formatter = treefmtEval.config.build.wrapper;

      devShells.default = pkgs.mkShell {
        packages = with pkgs; [
          cocogitto
          licensure
          flake_version_update.packages."${system}".default
          lpm.packages."${system}".default
          texlive

          zathura
        ];
      };
    });
}